program1472 > 자료실 > vb.net

[업데이트중] HttpWebRequest처럼 HTTP 요청을 보낼 수 있고, 더 다양한 기능이나 사용 편의성을 제공하는 .NET 호환 라이브러리 및 도구

하나를하더라도최선을 — 2025-07-02T19:00:29+09:00

1. HttpClient (System.Net.Http)

최신 .NET에서 권장되는 기본 HTTP 라이브러리
비동기/동기, 쿠키, 헤더, 인증, JSON 직렬화 등 지원
TLS 1.2 기본 지원, HttpWebRequest보다 사용 간결

Dim client As New HttpClient()

Dim response = Await client.GetAsync("https://example.com")

Dim content = Await response.Content.ReadAsStringAsync()

2. RestSharp

인기 있는 .NET용 REST API 클라이언트 라이브러리
HttpWebRequest보다 간단하게 REST 요청 구성 가능
JSON 직렬화, 인증, 쿠키 자동 처리 기능 내장

Dim client = New RestClient("https://example.com")

Dim request = New RestRequest("endpoint", Method.GET)

request.AddHeader("User-Agent", "...")

Dim response = client.Execute(request)

NuGet: Install-Package RestSharp

3. Flurl.Http

HttpClient를 래핑한 간결한 문법 제공
체이닝 방식으로 URL, 파라미터, 헤더 등 쉽게 구성 가능

Dim json = Await "https://example.com"

.WithHeader("User-Agent", "...")

.GetStringAsync()

NuGet: Install-Package Flurl.Http

4. WebClient (구버전)

매우 간단한 동기식 요청 도구
쿠키, 헤더 처리 제한적 / 기본 .NET 포함

Dim client As New WebClient()

Dim content As String = client.DownloadString("https://example.com")

5. Edge.js + Node.js (고급)

VB.NET에서 Node.js의 axios 또는 puppeteer 호출
매우 고급 상황에서 브라우저 수준 우회 요청 가능

목적	추천 라이브러리
고성능 REST API	`RestSharp`, `Flurl`
브라우저처럼 세밀 제어	`curl` or `puppeteer`
비동기 / 표준 HTTP 지원	`HttpClient`
단순 동기 요청	`WebClient`, `HttpWebRequest`

CreateObject("MSXML2.ServerXMLHTTP.6.0") 는 크롤링에 사용할 수 없을 것 같다.

    Private Function xWinHttp(Optional mesode As String = "GET", Optional URL As String = Nothing, Optional Hadders As String = Nothing, Optional enQuery As String = "") As Object

        Dim T As String = "", O As Object

Do

            If Not isWork Then Return Nothing

            If isDelay AndAlso delayValue > 0 Then

                program1472.Functions.Time.Delay(delayValue)

            End If

            Dim agent As String = userAgent()

Try

                ServicePointManager.SecurityProtocol = SecurityProtocolType.Tls12

                Static xhr As Object = CreateObject("MSXML2.ServerXMLHTTP.6.0")

                xhr.Open(mesode.ToUpper(), URL, False)

                xhr.setOption(2, 13056)

                xhr.setRequestHeader("User-Agent", agent)

                xhr.setRequestHeader("Accept", "application/json, text/plain, */*")

                xhr.setRequestHeader("Accept-Language", "ko-KR,ko;q=0.8,en-US;q=0.6,en;q=0.4")

                xhr.setRequestHeader("Referer", $"https://map.naver.com/p/search/{enQuery}?c=15.00%2C0%2C0%2C0%2Cdh")

                xhr.setRequestHeader("Cache-Control", "no-cache")

                xhr.setRequestHeader("Pragma", "no-cache")

                xhr.setRequestHeader("Expires", "Sat, 01 Jan 2000 00:00:00 GMT")

                xhr.setRequestHeader("Connection", "keep-alive")

                xhr.setRequestHeader("Sec-Fetch-Dest", "empty")

                xhr.setRequestHeader("Sec-Fetch-Mode", "cors")

                xhr.setRequestHeader("Sec-Fetch-Site", "same-origin")

                xhr.setRequestHeader("TE", "trailers")

                xhr.send

                T = xhr.responseText

            Catch ex As Exception

                T = ""

                userAgentOriginalList.Remove(agent)

                LOG(ex.Message)

                Threading.Thread.Sleep(1200) : Application.DoEvents()

            End Try

            If T.IndexOf(">일시적인 서비스 오류가 발생했습니다.<") > -1 Then

                userAgentOriginalList.Remove(agent)

                T = "" : LOG("[ERR] 과도한 트래픽으로 인한 일시적인 서비스 오류가 발생했습니다.")

                program1472.Functions.Time.Delay(12000, CType(MainForm, fMain).LOG_LIST)

                xWinHttp(, $"https://map.naver.com/p/search/{enQuery}?c=15.00%2C0%2C0%2C0%2Cdh")

            End If

        Loop Until T.Length > 0

        O = JSON.DeserializeObject(T)

        JSON.AddValue(O, "url", URL)

        Dim timestamp As String = DateTime.Now.ToString("yyyyMMdd_HHmmssfffff")

        Dim fileName As String = IO.Path.Combine(APP_EXPORT_PATH, $"{timestamp}.json")

        IO.File.WriteAllText(fileName, O.ToString)

        Return O

    End Function

동일 요청을 WinHttpRequest, HttpWebRequest, curl에서 보낼 때는 정상 응답을 받는데 MSXML2.ServerXMLHTTP.6.0은 오류를 토해낸다.

403 Forbidden

nginx

[vb.net] VB.NET에서 Excel 파일 데이터 추출(읽기) 방법

하나를하더라도최선을 — 2024-07-17T08:30:27+09:00

엑셀(Excel) 데이터 추출

VB.NET을 사용하여 엑셀 파일을 읽는 방법을 소개합니다. OfficeOpenXml 라이브러리를 활용하여 엑셀 파일을 열고, 첫 번째 워크시트에서 데이터를 추출하여 DataTable에 저장합니다. 각 행과 열을 반복하면서 셀 값들을 데이터 테이블에 추가하고, 최종적으로 완성된 데이터 테이블을 반환합니다. 이 함수는 엑셀 파일의 데이터 구조가 올바르지 않을 경우에는 적절한 로그 메시지를 출력하고 null을 반환하여 오류 처리를 합니다.

이 함수는 비상업적 용도로 라이센스를 설정할 수 있는 옵션을 제공하며, 엑셀 파일의 내용을 문자열로 처리하여 DataTable에 저장하는 예시를 제공합니다.

이 VB.NET 함수를 사용하면 엑셀 파일에서 데이터를 효과적으로 추출하고 관리할 수 있습니다.

NuGet 추가하기

NuGet에서 "EPPlus"를 검색해서 아래 사진처럼 설치 합니다.

Excel 파일 데이터 추출(읽기) 함수 (ReadExcelFile)

이 ExcelReader 클래스의 ReadExcelFile 함수는 지정된 엑셀 파일을 읽어 DataTable 형식으로 반환하는 기능을 제공합니다.

Imports System.IO

Imports OfficeOpenXml



Public Class ExcelReader

    Private Shared isOpen As Boolean



    Public Shared Function ReadExcelFile(filePath As String) As DataTable

        If Not isOpen Then OfficeOpenXml.ExcelPackage.LicenseContext = OfficeOpenXml.LicenseContext.NonCommercial ' 또는 LicenseContext.Commercial

        Dim dt As New DataTable()



        ' Load the Excel file

        Dim fileInfo As New FileInfo(filePath)

        Using package As New ExcelPackage(fileInfo)

            ' Get the first worksheet in the workbook

            Dim worksheet As ExcelWorksheet = package.Workbook.Worksheets(0)

            If worksheet.Dimension Is Nothing Then

                program1472.LOG("데이터 구조가 올바르지 않습니다.",, 1)

                Return Nothing

            End If

            ' Loop through all rows from the first row (start from 1 to skip header row)

            For row As Integer = worksheet.Dimension.Start.Row To worksheet.Dimension.End.Row

                ' Create a new DataRow

                Dim newRow As DataRow = dt.NewRow()



                ' Loop through all columns in the current row

                For col As Integer = worksheet.Dimension.Start.Column To worksheet.Dimension.End.Column

                    ' Add the cell value to the DataRow

                    If Not dt.Columns.Contains((col - 1).ToString) Then dt.Columns.Add((col - 1).ToString, GetType(String))

                    newRow(col - 1) = If(worksheet.Cells(row, col).Value IsNot Nothing, worksheet.Cells(row, col).Value.ToString(), Nothing)

                Next



                ' Add the DataRow to the DataTable

                dt.Rows.Add(newRow)

            Next

        End Using



        Return dt

    End Function

End Class

장점

간편한 데이터 추출

OfficeOpenXml 라이브러리를 이용하여 엑셀 파일을 손쉽게 열고 데이터를 추출할 수 있습니다. 필요한 데이터를 한 번에 DataTable 형식으로 변환하여 처리할 수 있어 개발 시간을 단축시킵니다.

유연성과 확장성

엑셀 파일의 첫 번째 워크시트에서 데이터를 읽지만, 필요에 따라 다른 워크시트나 특정 범위의 데이터를 읽도록 함수를 수정할 수 있습니다. 이는 다양한 엑셀 데이터 처리 요구사항에 대응할 수 있는 유연성을 제공합니다.

오류 처리 기능

함수는 데이터 구조가 올바르지 않은 경우에 대비하여 적절한 오류 메시지를 출력하고 처리를 중단합니다. 이로 인해 예기치 않은 데이터 처리 오류를 방지할 수 있습니다.

비상업적 용도 지원

OfficeOpenXml 라이브러리는 비상업적 용도로 라이센스를 설정할 수 있는 옵션을 제공하므로, 개인 프로젝트나 교육적 목적에서 자유롭게 활용할 수 있습니다.

이 VB.NET 함수를 사용하면 엑셀 파일에서 데이터를 효과적으로 추출하고 관리할 수 있습니다.

이와 같은 엑셀 파일을 데이터 테이블로 변환하여 DataGridView로 보여줍니다.

Example:

    Private Sub BhsButton3_Click(sender As Object, e As EventArgs) Handles BhsButton3.Click

        Dim filePath As String = program1472.Functions.File.OpenFilePicker(program1472.Functions.File.getfilter("excel"))

        template = ExcelReader.ReadExcelFile(filePath)

        BhsDataGridView1.DataSource = template

    End Sub

Imports System.IO

Imports System.Windows.Forms



Namespace Functions

    Public Class [File]

        Public Shared Function getfilter(datatype As String) As String

            Select Case datatype.ToLower

                Case "img", "image", "이미지", "사진" : Return "이미지 파일 선택 (*.jpg;*.jpeg;*.png)|*.jpg;*.jpeg;*.png"

                Case "pdf" : Return "PDF 파일 선택 (*.pdf)|*.pdf"

                Case "excel" : Return "Excel 파일 선택 (Excel Files)|*.xls;*.xlsx;*.xlsm"

                Case Else : Return String.Format("{0} 파일 (*.{0})|*.{0}", datatype)

            End Select

        End Function



        Public Shared Function OpenFilePicker(filter As String, Optional title As String = "Please select a file") As String

            Using openFileDialog As New OpenFileDialog()

                openFileDialog.Title = title

                openFileDialog.Filter = filter

                openFileDialog.RestoreDirectory = True



                If openFileDialog.ShowDialog() = DialogResult.OK Then

                    Return openFileDialog.FileName

                Else

                    Return String.Empty

                End If

            End Using

        End Function    

	End Class

End Namespace

[vb.net] VB.NET에서 Excel 파일 데이터 추출(읽기) 방법

하나를하더라도최선을 — 2024-07-16T10:51:51+09:00

엑셀(Excel) 데이터 추출

이 VB.NET 함수를 사용하면 엑셀 파일에서 데이터를 효과적으로 추출하고 관리할 수 있습니다.

NuGet 추가하기

NuGet에서 "EPPlus"를 검색해서 아래 사진처럼 설치 합니다.

Excel 파일 데이터 추출(읽기) 함수 (ReadExcelFile)

이 ExcelReader 클래스의 ReadExcelFile 함수는 지정된 엑셀 파일을 읽어 DataTable 형식으로 반환하는 기능을 제공합니다.

Imports System.IO

Imports OfficeOpenXml



Public Class ExcelReader

    Private Shared isOpen As Boolean



    Public Shared Function ReadExcelFile(filePath As String) As DataTable

        If Not isOpen Then OfficeOpenXml.ExcelPackage.LicenseContext = OfficeOpenXml.LicenseContext.NonCommercial ' 또는 LicenseContext.Commercial

        Dim dt As New DataTable()



        ' Load the Excel file

        Dim fileInfo As New FileInfo(filePath)

        Using package As New ExcelPackage(fileInfo)

            ' Get the first worksheet in the workbook

            Dim worksheet As ExcelWorksheet = package.Workbook.Worksheets(0)

            If worksheet.Dimension Is Nothing Then

                program1472.LOG("데이터 구조가 올바르지 않습니다.",, 1)

                Return Nothing

            End If

            ' Loop through all rows from the first row (start from 1 to skip header row)

            For row As Integer = worksheet.Dimension.Start.Row To worksheet.Dimension.End.Row

                ' Create a new DataRow

                Dim newRow As DataRow = dt.NewRow()



                ' Loop through all columns in the current row

                For col As Integer = worksheet.Dimension.Start.Column To worksheet.Dimension.End.Column

                    ' Add the cell value to the DataRow

                    If Not dt.Columns.Contains((col - 1).ToString) Then dt.Columns.Add((col - 1).ToString, GetType(String))

                    newRow(col - 1) = If(worksheet.Cells(row, col).Value IsNot Nothing, worksheet.Cells(row, col).Value.ToString(), Nothing)

                Next



                ' Add the DataRow to the DataTable

                dt.Rows.Add(newRow)

            Next

        End Using



        Return dt

    End Function

End Class

장점

간편한 데이터 추출

유연성과 확장성

오류 처리 기능

비상업적 용도 지원

이 VB.NET 함수를 사용하면 엑셀 파일에서 데이터를 효과적으로 추출하고 관리할 수 있습니다.

이와 같은 엑셀 파일을 데이터 테이블로 변환하여 DataGridView로 보여줍니다.

Example:

    Private Sub BhsButton3_Click(sender As Object, e As EventArgs) Handles BhsButton3.Click

        Dim filePath As String = program1472.Functions.File.OpenFilePicker(program1472.Functions.File.getfilter("excel"))

        template = ExcelReader.ReadExcelFile(filePath)

        BhsDataGridView1.DataSource = template

    End Sub

Imports System.IO

Imports System.Windows.Forms



Namespace Functions

    Public Class [File]

        Public Shared Function getfilter(datatype As String) As String

            Select Case datatype.ToLower

                Case "img", "image", "이미지", "사진" : Return "이미지 파일 선택 (*.jpg;*.jpeg;*.png)|*.jpg;*.jpeg;*.png"

                Case "pdf" : Return "PDF 파일 선택 (*.pdf)|*.pdf"

                Case "excel" : Return "Excel 파일 선택 (Excel Files)|*.xls;*.xlsx;*.xlsm"

                Case Else : Return String.Format("{0} 파일 (*.{0})|*.{0}", datatype)

            End Select

        End Function



        Public Shared Function OpenFilePicker(filter As String, Optional title As String = "Please select a file") As String

            Using openFileDialog As New OpenFileDialog()

                openFileDialog.Title = title

                openFileDialog.Filter = filter

                openFileDialog.RestoreDirectory = True



                If openFileDialog.ShowDialog() = DialogResult.OK Then

                    Return openFileDialog.FileName

                Else

                    Return String.Empty

                End If

            End Using

        End Function    

	End Class

End Namespace

[vb.net] 윈도우 폼에서 자식 컨트롤의 특정(Closed) 메서드 자동 호출하기

하나를하더라도최선을 — 2024-07-12T10:54:54+09:00

윈도우 폼 애플리케이션을 개발할 때 종종 각 컨트롤이 폼이 닫힐 때 특정 작업을 수행해야 할 필요가 있습니다.

예를 들어, 데이터를 저장하거나 리소스를 정리하는 등의 작업이 이에 해당합니다.

이를 위해 유용한 방법 중 하나는 컨트롤이 자체적으로 Closed 메서드를 구현하여 이러한 작업을 처리하는 것입니다.

여기서 소개할 소스 코드는 간단한 윈도우 폼의 FormClosed 이벤트에서 모든 컨트롤에 대해 Closed 메서드를 호출하는 방법을 구현한 것입니다.

이 방법은 각 컨트롤이 자체적으로 Closed 메서드를 구현하고 있는지 확인하고, 구현되어 있다면 해당 메서드를 실행합니다.

Private Sub fMain_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed

    For Each ctl As Object In Me.Controls

        If HasClosedMethod(ctl) Then

            Dim method As MethodInfo = ctl.GetType().GetMethod("Closed")

            method.Invoke(ctl, Nothing)

        Else

            Console.WriteLine("Closed 메서드가 구현되지 않은 컨트롤입니다.")

        End If

    Next

End Sub

' 컨트롤이 Closed 메서드를 구현했는지 확인하는 함수

Private Function HasClosedMethod(control As Control) As Boolean

    Dim method As MethodInfo = control.GetType().GetMethod("Closed")

    Return method IsNot Nothing AndAlso method.ReturnType Is GetType(Void)

End Function

위 소스 코드는 다음과 같은 기능을 수행합니다:

fMain_FormClosed 메서드: 이는 윈도우 폼의 FormClosed 이벤트 핸들러로서, 폼이 닫힐 때마다 폼 안에 있는 모든 컨트롤을 순회합니다.
HasClosedMethod 함수: 이 함수는 각 컨트롤이 Closed 메서드를 구현하고 있는지를 확인합니다. 만약 해당 메서드가 구현되어 있다면 True를 반환하고, 그렇지 않으면 False를 반환합니다.

사용 예시

이 소스 코드를 사용하면 각 컨트롤이 자체적으로 폼이 닫힐 때 수행할 작업을 정의할 수 있습니다. 예를 들어, 텍스트 상자 컨트롤에서 데이터를 저장하거나, 파일 브라우저에서 열린 파일을 닫는 등의 작업을 Closed 메서드에 구현할 수 있습니다. 이를 통해 코드의 유지보수성을 높이고, 각 컨트롤의 역할을 명확히 할 수 있습니다.

결론

윈도우 폼 개발에서 각 컨트롤이 폼이 닫힐 때 수행해야 할 작업을 자동으로 처리하려면 Closed 메서드를 구현하는 것이 효과적일 수 있습니다. 위에서 소개한 소스 코드를 참고하여, 여러분의 애플리케이션에서 이를 활용해 보세요. 각 컨트롤의 특정 동작을 명확히 정의하고, 코드의 재사용성과 가독성을 높이는 데 도움이 될 것입니다.

[vb.net] Windows 시스템 오디오 볼륨 가져오기 및 설정

하나를하더라도최선을 — 2024-06-04T16:22:49+09:00

소개

출처 입력

현재 시스템 출력 볼륨을 검색하거나 설정하는 메서드를 제공하는 .NET 클래스가 없습니다.

이 문서에서는 Windows 멀티미디어 장치 API에 대한 인터페이스를 사용하여 솔루션을 제공합니다.

배경

이 웹 페이지에서 이 기사에 대한 아이디어를 얻었습니다.

VB .NET 또는 C# 소스 코드에 삽입하여 즉시 사용할 수 있도록 조금 다듬었습니다.

코드 사용

현재 시스템 오디오 볼륨 설정값을 정수(0~100)로 검색하려면 함수를 호출하세요 GetVolume().

ex)

Dim currentVolume As Integer = GetVolume()

현재 시스템 오디오 볼륨 설정을 새 값(0 - 100)으로 설정하려면 함수를 호출하십시오 SetVolume().

ex)

SetVolume(30)

다음은 Windows 멀티미디어 API를 호출하여 Windows 시스템 오디오 볼륨을 가져오거나 설정하는 VB.NET 및 C# 메서드의 소스 코드입니다.

Option Strict Off

Imports System

Imports System.Runtime.InteropServices



Module WindowsSystemAudio

    

    

    Private Interface IMMDeviceEnumerator

#Disable Warning IDE1006 ' Naming Styles

        Sub lpVtbl()

#Enable Warning IDE1006 ' Naming Styles

        Function GetDefaultAudioEndpoint(ByVal dataFlow As Integer, _

        ByVal role As Integer,  ByRef ppDevice As IMMDevice) As Integer

    End Interface



    Private NotInheritable Class MMDeviceEnumeratorFactory

        Public Shared Function CreateInstance() As IMMDeviceEnumerator

            Return CType(Activator.CreateInstance_

            (Type.GetTypeFromCLSID(New Guid_

            ("BCDE0395-E52F-467C-8E3D-C4579291692E"))), _

            IMMDeviceEnumerator) ' a MMDeviceEnumerator

        End Function

    End Class



    

    Private Interface IMMDevice

        Function Activate(

     ByVal iid As Guid, _

     ByVal dwClsCtx As Integer, ByVal pActivationParams As IntPtr, 

     ByRef ppInterface As Object) As Integer

    End Interface



    

    Public Interface IAudioEndpointVolume

        Function RegisterControlChangeNotify(ByVal pNotify As IntPtr) As Integer

        Function UnregisterControlChangeNotify(ByVal pNotify As IntPtr) As Integer

        Function GetChannelCount(ByRef pnChannelCount As UInteger) As Integer

        Function SetMasterVolumeLevel(ByVal fLevelDB As Single, _

        ByVal pguidEventContext As Guid) As Integer

        Function SetMasterVolumeLevelScalar_

        (ByVal fLevel As Single, ByVal pguidEventContext As Guid) As Integer

        Function GetMasterVolumeLevel(ByRef pfLevelDB As Single) As Integer

        Function GetMasterVolumeLevelScalar(ByRef pfLevel As Single) As Integer

    End Interface



    Friend Sub SetVolume(ByVal Level As Integer)

        Try

            Dim deviceEnumerator As IMMDeviceEnumerator = _

                                 MMDeviceEnumeratorFactory.CreateInstance()

            Dim speakers As IMMDevice = Nothing

            Dim res As Integer

            Const eRender = 0

            Const eMultimedia = 1

            deviceEnumerator.GetDefaultAudioEndpoint(eRender, eMultimedia, speakers)

            Dim Audio_EndPointVolume As IAudioEndpointVolume = Nothing

            speakers.Activate(GetType(IAudioEndpointVolume).GUID, 0, _

                              IntPtr.Zero, Audio_EndPointVolume)

            Dim ZeroGuid As New Guid()

            res = Audio_EndPointVolume.SetMasterVolumeLevelScalar_

                  (Level / 100.0F, ZeroGuid)

        Catch ex As Exception

        End Try

    End Sub



    Friend Function GetVolume() As Integer

        Try

            Dim currentLevel As Single = 0 ' Expressed as a decimal value

            Dim deviceEnumerator As IMMDeviceEnumerator = _

                                 MMDeviceEnumeratorFactory.CreateInstance()

            Dim speakers As IMMDevice = Nothing

            Dim res As Integer

            Const eRender = 0

            Const eMultimedia = 1

            deviceEnumerator.GetDefaultAudioEndpoint(eRender, eMultimedia, speakers)

            Dim Audio_EndPointVolume As IAudioEndpointVolume = Nothing

            speakers.Activate(GetType(IAudioEndpointVolume).GUID, _

                              0, IntPtr.Zero, Audio_EndPointVolume)

            res = Audio_EndPointVolume.GetMasterVolumeLevelScalar(currentLevel)

            Return CInt(100 * currentLevel)  ' Returned as an Integer 0 - 100

        Catch ex As Exception

            Return -1

        End Try

    End Function

End Module

[vb.net] Form 전체화면 실행 시 Window작업표시줄 숨기는방법

하나를하더라도최선을 — 2024-06-03T18:15:25+09:00

주어진 코드는 윈도우 폼을 사용하여 사용자 지정 닫기 버튼이 있는 풀스크린 애플리케이션을 만드는 예시입니다.

Imports System.Runtime.InteropServices

 
Public Class fMain
 
    ' 윈도우 API 함수 선언
    <DllImport("user32.dll")>
    Private Shared Function FindWindow(lpClassName As String, lpWindowName As String) As IntPtr
    End Function
 
    <DllImport("user32.dll", SetLastError:=True)>
    Private Shared Function SetWindowPos(ByVal hWnd As IntPtr, ByVal hWndInsertAfter As IntPtr, ByVal X As Integer, ByVal Y As Integer, ByVal cx As Integer, ByVal cy As Integer, ByVal uFlags As SetWindowPosFlags) As Boolean
    End Function
 
    ' SetWindowPos 함수의 플래그 열거형
    <Flags>
    Private Enum SetWindowPosFlags As UInteger
        SynchronousWindowPosition = &H4000
        DeferErase = &H2000
        DrawFrame = &H20
        FrameChanged = &H20
        HideWindow = &H80
        DoNotActivate = &H10
        DoNotCopyBits = &H100
        IgnoreMove = &H2
        DoNotChangeOwnerZOrder = &H200
        DoNotRedraw = &H8
        DoNotReposition = &H200
        DoNotSendChangingEvent = &H400
        IgnoreResize = &H1
        IgnoreZOrder = &H4
        ShowWindow = &H40
    End Enum
 
    ' 사용자 지정 닫기 버튼 PictureBox
    Private cmd_close As PictureBox
 
    ' 폼이 로드될 때 발생하는 이벤트 처리기
    Private Sub fMain_Load(sender As Object, e As EventArgs) Handles MyBase.Load
        ' 사용자 지정 닫기 버튼 생성
        cmd_close = New PictureBox
        cmd_close.Image = My.Resources.ResourceManager.GetObject("close") ' 리소스에서 이미지 가져오기
        cmd_close.Size = New Size(17, 17) ' 크기 설정
        cmd_close.SizeMode = PictureBoxSizeMode.Zoom ' 이미지 크기 조정 방법 설정
        Me.Controls.Add(cmd_close) ' 폼에 PictureBox 추가
        ' 사용자 지정 닫기 버튼 클릭 이벤트 핸들러 추가
        AddHandler cmd_close.Click, Sub(xs As Object, xe As EventArgs)
                                        Application.Exit() ' 애플리케이션 종료
                                    End Sub
 
        ' 폼 설정
        Me.FormBorderStyle = FormBorderStyle.None ' 테두리 스타일 없음
        Dim window As IntPtr = FindWindow("Shell_traywnd", "") ' 작업 표시줄 찾기
        SetWindowPos(window, IntPtr.Zero, 0, 0, 0, 0, SetWindowPosFlags.HideWindow) ' 작업 표시줄 숨기기
        Me.WindowState = FormWindowState.Maximized ' 최대화
        Me.TopMost = True ' 항상 위에 표시
    End Sub
 
    ' 폼이 Dispose될 때 발생하는 이벤트 처리기
    Private Sub MyBase_Disposed(sender As Object, e As EventArgs) Handles Me.Disposed
        Dim window As IntPtr = FindWindow("Shell_traywnd", "") ' 작업 표시줄 찾기
        SetWindowPos(window, IntPtr.Zero, 0, 0, 0, 0, SetWindowPosFlags.ShowWindow) ' 작업 표시줄 다시 표시
    End Sub
 
    ' 폼 크기 조정 이벤트 처리기
    Private Sub fMain_Resize(sender As Object, e As EventArgs) Handles Me.Resize
        Dim S As Size = Me.ClientRectangle.Size ' 클라이언트 영역 크기 가져오기
        If cmd_close IsNot Nothing Then cmd_close.Location = New Point(S.Width - cmd_close.Width - 15, 15) ' 사용자 지정 닫기 버튼 위치 설정
    End Sub
 
End Class
 

위 코드에서는 FindWindow 및 SetWindowPos와 같은 윈도우 API 함수를 사용하여 작업 표시줄을 숨기거나 표시합니다. 

사용자 지정 닫기 버튼을 클릭하면 애플리케이션이 종료됩니다. 폼이 로드되면 작업 표시줄이 숨겨지고, 폼이 닫힐 때 작업 표시줄이 다시 표시됩니다. 

사용자 지정 닫기 버튼은 폼의 우측 상단에 표시됩니다.

[VB.NET] 무명 함수(Anonymous Function), 람다 함수(Lambda Function): 코드 작성을 더욱 효율적으로 만드는 무기

하나를하더라도최선을 — 2024-05-08T13:58:25+09:00

람다 함수는 매우 유연하고 간결하며 간편한 방법으로 코드를 작성할 수 있도록 해줍니다.

소개: 람다 함수는 현대 프로그래밍에서 매우 중요한 역할을 하고 있습니다. 그것은 익명 함수로, 코드를 더 간결하고 유연하게 만들어줍니다. 이번 포스트에서는 람다 함수의 개념과 사용 사례에 대해 자세히 알아보겠습니다.

1. 람다 함수란?

람다 함수는 익명 함수로, 함수를 정의하고 사용하는 동시에 코드 안에서 직접 정의됩니다. 이는 함수를 명시적으로 정의하지 않고도 간단하고 짧은 코드 조각을 생성할 수 있도록 해줍니다. 람다 함수의 기본 구조는 다음과 같습니다:

Function(parameters) expression

예를 들어, (x, y) => x + y는 두 개의 매개변수를 더하는 람다 함수를 나타냅니다.

2. 람다 함수의 구문과 사용 방법

람다 함수는 주로 델리게이트(Delegate)나 LINQ 쿼리, 함수형 프로그래밍 등에서 사용됩니다. 예를 들어, 리스트의 각 요소를 제곱하는 간단한 람다 함수는 다음과 같습니다:

3. 람다 함수의 주요 활용 사례

정렬(Sorting), 필터링(Filtering), 매핑(Mapping) 등 데이터 처리 작업에서의 활용
LINQ 쿼리에서의 람다 함수 사용
이벤트 핸들러 등에서의 람다 함수 활용

4. 람다 함수의 장단점

장점: 코드의 간결성, 유연성, 가독성 향상
단점: 복잡한 람다 함수의 가독성 저하와 디버깅의 어려움

람다 함수의 주요 장점은 코드의 간결성과 가독성을 향상시키는 것입니다. 그러나 복잡한 람다 함수는 가독성이 저하될 수 있고, 디버깅이 어려울 수 있습니다.

5. 람다 함수의 사용 지침과 Best Practices

가독성을 위한 람다 함수 사용 지침
긴 람다 함수의 경우 메서드 추출을 통한 리팩토링 고려 사항

6. 결론

람다 함수는 코드 작성을 더욱 효율적으로 만들어주는 강력한 도구입니다. 그것을 잘 활용하면 코드의 가독성과 유연성을 향상시킬 수 있으며, 프로그래밍 생산성에 기여할 수 있습니다.

1. 정렬(Sorting):

Dim numbers As List(Of Integer) = New List(Of Integer) From {5, 2, 8, 1, 9}

numbers.Sort(Function(x, y) x.CompareTo(y))

2. 필터링(Filtering):

Dim numbers As List(Of Integer) = New List(Of Integer) From {5, 2, 8, 1, 9}

Dim evenNumbers = numbers.Where(Function(x) x Mod 2 = 0).ToList()

3. 객체 매핑(Object Mapping):

Dim names As List(Of String) = New List(Of String) From {"Alice", "Bob", "Charlie"}

Dim nameLengths = names.Select(Function(name) name.Length).ToList()

4. 사전 정의된 동작(Predefined Actions):

Dim numbers As List(Of Integer) = New List(Of Integer) From {5, 2, 8, 1, 9}

Dim sum = numbers.Aggregate(Function(acc, x) acc + x)

5. 조건부 작업(Conditional Operations):

Dim numbers As List(Of Integer) = New List(Of Integer) From {5, 2, 8, 1, 9}

Dim max = numbers.Max(Function(x, y) If(x > y, x, y))

[VB.NET] 컨트롤 삭제 여부 확인하는 방법

하나를하더라도최선을 — 2024-05-08T13:22:03+09:00

컨트롤이 삭제되었는지 확인하기 위해서는 해당 컨트롤이 유효한지 확인해야 합니다. 이를 위해 다음과 같은 VB.NET 코드를 사용할 수 있습니다.

Module ControlExtensions

    <Extension()>

    Public Function IsDisposed(ByVal control As Control) As Boolean

        If control Is Nothing Then Return True

        If control.Disposing OrElse control.IsDisposed Then Return True

        Dim parent = control.Parent

        While parent IsNot Nothing

            If parent.Disposing OrElse parent.IsDisposed Then Return True

            parent = parent.Parent

        End While

        Return False

    End Function

End Module

이 확장 메서드를 사용하여 특정 컨트롤이 삭제되었는지 확인할 수 있습니다. 아래는 예제 코드입니다.

' 사용 예제

If myControl.IsDisposed() Then

    ' 컨트롤이 삭제되었음을 처리

Else

    ' 컨트롤이 여전히 존재함을 처리

End If

위의 예제 코드에서 myControl은 삭제 여부를 확인하려는 컨트롤입니다. 이 코드는 컨트롤이 삭제되었으면 True를 반환하고, 그렇지 않으면 False를 반환합니다.

example:)

If myControl Is Nothing OrElse myControl.IsDisposed Then myControl = New TextBox

VB.NET에서 System.Reflection을 이용한 동적 DLL 사용하기: 예제와 설명

하나를하더라도최선을 — 2024-04-25T12:14:59+09:00

VB.NET에서 동적 DLL을 사용하는 방법은 매우 유용합니다. 동적 DLL은 프로그램 실행 중에 로드되어 사용되며, 라이브러리의 업데이트나 유지 관리를 용이하게 합니다. 아래 예제를 통해 VB.NET에서 동적 DLL을 사용하는 방법을 자세히 살펴보겠습니다.

Imports System.Runtime.InteropServices

Module MainModule

    ' DLL 함수의 프로토타입 정의

    <DllImport("example.dll", CallingConvention:=CallingConvention.Cdecl)>

    Public Function Add(ByVal a As Integer, ByVal b As Integer) As Integer

    End Function

    Sub Main()

        ' DLL 함수 호출

        Dim result As Integer = Add(5, 3)

        Console.WriteLine("결과: " & result)

    End Sub

End Module

위 코드는 "example.dll"이라는 DLL을 동적으로 호출하여 두 숫자를 더하는 간단한 예제입니다. 
이를 실행하면 DLL의 함수를 성공적으로 호출하여 결과를 출력할 것입니다.
이 예제를 통해 VB.NET에서 동적 DLL을 사용하는 기본적인 방법을 이해할 수 있습니다. 
동적 DLL을 사용하면 프로그램의 유연성을 높일 수 있으며, 여러 라이브러리를 효율적으로 관리할 수 있습니다.
이런식으로 우리는 Windows API라고 많이 알고 사용하는 방식 중 하나입니다.

System.Reflection을 이용한 동적 DLL 사용 VB.NET에서 System.Reflection 네임스페이스를 활용하여 동적 DLL을 사용하는 방법은 유연하고 강력한 방법입니다. 
이를 통해 실행 중에 DLL을 로드하고 메서드를 호출할 수 있습니다. 
아래 예제를 통해 VB.NET에서 System.Reflection을 이용한 동적 DLL 사용하는 방법을 자세히 알아보겠습니다.

 Imports System
 
Namespace ExampleNamespace
    Public Class ExampleClass
        Public Function Add(ByVal a As Integer, ByVal b As Integer) As Integer
            Return a + b
        End Function
    End Class
End Namespace
위 코드를 ExampleClass.vb 파일로 저장하세요. 그리고 다음 명령어를 사용하여 컴파일하여 example.dll을 생성할 수 있습니다.
이제 example.dll이 준비되었습니다. 이제 VB.NET 코드에서 이 DLL을 사용하는 방법을 보여줄게요.

 Imports System.Reflection
 
Module MainModule
    Sub Main()
        ' DLL 파일 경로 설정
        Dim dllPath As String = "C:\path\to\your\example.dll"
 
        ' DLL 파일 로드
        Dim assembly As Assembly = Assembly.LoadFrom(dllPath)
 
        ' DLL 내의 클래스 및 메서드 정보 가져오기
        Dim className As String = "ExampleNamespace.ExampleClass"
        Dim methodName As String = "Add"
 
        Dim type As Type = assembly.GetType(className)
        Dim methodInfo As MethodInfo = type.GetMethod(methodName)
 
        ' 메서드 호출
        Dim instance As Object = Activator.CreateInstance(type)
        Dim result As Integer = CType(methodInfo.Invoke(instance, New Object() {5, 3}), Integer)
 
        ' 결과 출력
        Console.WriteLine("결과: " & result)
    End Sub
End Module

위 코드를 실행하면, example.dll을 동적으로 호출하여 두 숫자를 더하는 결과를 출력할 수 있습니다.

다음으로 관련하여 예제를 하나 더 설명드리겠습니다.

아래는 DLL을 만들기 위한 예제 코드와, 해당 DLL을 사용하는 VB.NET 코드입니다.

DLL 만들기 (ExampleClass.vb):

Public Class ExampleClass

Public Shared Function Add(ByVal a As Integer, ByVal b As Integer) As Integer

MsgBox(a.ToString() & " + " & b.ToString() & " = " & (a + b).ToString())

Return a + b

End Function

End Class

DLL을 사용하는 VB.NET 코드:

Imports System.Reflection

Module MainModule

Sub Main()

' DLL 파일 경로 설정

Dim dllPath As String = "DLL의_경로\example.dll"

' DLL 파일 로드

Dim assembly As Assembly = Assembly.LoadFile(dllPath)

' DLL 내의 클래스 및 메서드 정보 가져오기

Dim className As String = "루트네임스페이스.ExampleClass"

Dim methodName As String = "Add"

Dim type As Type = assembly.GetType(className)

Dim methodInfo As MethodInfo = type.GetMethod(methodName)

' 메서드 호출

Dim returnValue As Integer = DirectCast(methodInfo.Invoke(Nothing, New Object() {5, 3}), Integer)

' 결과 출력

Console.WriteLine("결과: " & returnValue.ToString())

End Sub

End Module

위 코드를 실행하면, example.dll을 동적으로 호출하여 두 숫자를 더하는 결과를 출력할 수 있습니다.

VB.NET 마스터하기: 효율적인 Extension 메서드 사용법

하나를하더라도최선을 — 2024-04-17T15:36:51+09:00

VB.NET에서의 Extension 메서드는 기존 타입에 새로운 메서드를 추가하고자 할 때 유용하게 사용할 수 있는 기능입니다. 이를 통해 기존의 클래스, 구조체, 인터페이스 등에 새로운 기능을 추가할 수 있으며, 원본 소스 코드를 변경하지 않고도 기능을 확장할 수 있습니다.

Extension 메서드 정의하는 방법

VB.NET에서 Extension 메서드를 정의하려면 다음과 같은 절차를 따릅니다:

모듈 선언: Extension 메서드는 모듈 내에 정의되어야 합니다. 모듈은 일반적으로 Module 키워드를 사용하여 선언합니다.
속성 사용: 메서드 앞에 속성을 명시하여 이 메서드가 Extension 메서드임을 나타냅니다.
첫 번째 파라미터는 ByVal 이어야 하며, 확장하고자 하는 타입을 정의합니다: 이 파라미터는 Extension 메서드가 적용될 타입의 인스턴스를 참조합니다.

예제: String 타입에 메서드 추가하기

다음은 String 타입에 IsFirstLetterUpperCase라는 Extension 메서드를 추가하는 예제입니다:

Imports System.Runtime.CompilerServices

Module StringExtensions

    <Extension()>

    Public Function IsFirstLetterUpperCase(ByVal s As String) As Boolean

        If String.IsNullOrEmpty(s) Then

            Return False

        End If

        Return Char.IsUpper(s(0))

    End Function

End Module

위 코드에서, IsFirstLetterUpperCase 메서드는 문자열의 첫 글자가 대문자인지 여부를 반환합니다. Module 내에서 정의되며, 속성을 사용해 이것이 Extension 메서드임을 나타냅니다.

사용 방법

Extension 메서드를 정의한 후에는 다음과 같이 사용할 수 있습니다:

Dim result As Boolean = "Hello".IsFirstLetterUpperCase()

Console.WriteLine(result) ' 출력: True

"Hello" 문자열에 대하여 IsFirstLetterUpperCase 메서드를 직접 호출하여, 첫 글자가 대문자인지를 평가합니다.

주의사항

Extension 메서드는 해당 타입의 메서드처럼 보이지만, 실제로는 정적 메서드이기 때문에 오버라이드할 수 없습니다.
너무 많은 Extension 메서드를 추가하면 코드의 복잡성이 증가할 수 있으므로, 필요하고 의미 있는 경우에만 추가하는 것이 좋습니다.

VB.NET에서의 Extension 메서드는 코드를 보다 유연하고 재사용 가능하게 만들어 주며, 기존의 타입에 간단하게 새로운 기능을 추가할 수 있는 좋은 방법입니다.

또 다른 예:

Imports System.Runtime.CompilerServices

Module Module1

    <Extension()>

    Public Function ToString(Of I)(L As List(Of I), stri As Integer) As String

        If L.Count >= (stri + 1) Then

            Return L.Item(stri).ToString

        End If

        Return Nothing

    End Function

End Module

위 함수 사용법 :

Dim U As New List(Of String)
U.AddRange({"가", "을", "하"})
MsgBox(U.ToString(1))

여기서 리스트중 1번째인 "을"을 반환한다.
 

정규식(정규 표현식, Regular Expression)

하나를하더라도최선을 — 2024-04-17T14:40:41+09:00

정규식(정규 표현식, Regular Expression)은 텍스트에서 특정 패턴을 찾기 위해 사용하는 문자열입니다. 컴퓨터 과학에서 널리 사용되는 이 툴은 복잡한 검색과 문자열 치환 작업을 간편하게 수행할 수 있게 해줍니다. 여러 프로그래밍 언어 및 텍스트 편집 도구에서 지원합니다.

정규식의 기본 구성 요소

리터럴(Literals): 텍스트 그대로의 문자입니다. 예를 들어, 정규식 abc는 "abc"라는 문자열과 일치합니다.
메타 문자(Meta Characters): 특별한 의미를 가진 문자로, 패턴을 구성하는 데 사용됩니다. 자주 사용되는 메타 문자에는 다음이 포함됩니다.
- .: 어떤 한 문자와 일치 (개행 문자 제외)
- ^: 입력의 시작과 일치
- $: 입력의 끝과 일치
- *: 앞의 요소가 0회 이상 반복
- +: 앞의 요소가 1회 이상 반복
- ?: 앞의 요소가 0회 또는 1회 등장
- |: or 조건을 표현 (A|B는 A 또는 B)
- \: 다음 문자를 리터럴로 취급 (메타 문자가 아닌 문자로)
문자 클래스(Character Classes): 특정 집합 중 하나의 문자와 일치시킵니다.
- [abc]: 'a', 'b', 또는 'c'와 일치
- [^abc]: 'a', 'b', 'c'를 제외한 모든 문자와 일치
- [a-z]: 모든 소문자와 일치
- [A-Z]: 모든 대문자와 일치
- [0-9]: 모든 숫자와 일치
- \d: 모든 숫자와 일치 (digit)
- \D: 숫자가 아닌 모든 문자와 일치
- \w: 알파벳 문자, 숫자, 언더스코어(_)와 일치
- \W: \w가 아닌 문자와 일치
- \s: 모든 공백 문자 (스페이스, 탭, 줄바꿈 등)와 일치
- \S: 공백이 아닌 모든 문자와 일치
수량자(Quantifiers): 앞선 문자 또는 그룹이 몇 번 반복되는지를 지정합니다.
- {n}: 정확히 n번 반복
- {n,}: 최소 n번 반복
- {n,m}: 최소 n번 최대 m번 반복
그룹화(Grouping): 소괄호 ()를 사용하여 표현식을 그룹으로 묶습니다. 그룹화를 통해 여러 작업을 수행할 수 있으며, 추출이나 참조가 가능합니다.

정규식의 활용 예시

이메일 주소 검증: ^[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\.[a-zA-Z]{2,}$
전화번호 형식 확인: \d{2,3}-\d{3,4}-\d{4}
URL 확인: https?://(?:www\.)?.+

1. 이메일 주소 검증

이메일의 유효성을 확인하기 위해 다음과 같은 정규식을 사용할 수 있습니다.

regexCopy code

^[a-zA-Z0-9._%+-]+@[a-zA-Z0-9.-]+\.[a-zA-Z]{2,}$

이 정규식은 이메일이 일반적으로 사용되는 문자로 시작하고, "@" 기호, 도메인 이름, 마지막으로 점(".") 뒤에 두 글자 이상의 도메인 확장자가 오는 패턴을 검사합니다.

2. URL 유효성 검사

웹사이트 주소(URL)의 유효성을 검사하기 위해 사용될 수 있는 정규식입니다.

regexCopy code

https?://(?:www\.)?[-a-zA-Z0-9@:%._\+~#=]{2,256}\.[a-z]{2,6}\b(?:/[-a-zA-Z0-9@:%_\+.~#?&//=]*)?

이 패턴은 http 또는 https로 시작하고, 선택적으로 www.가 포함되며, 도메인 이름과 확장자를 포함하고, 선택적으로 경로와 쿼리 문자열을 포함할 수 있습니다.

3. 전화번호 형식 확인

다양한 형태의 전화번호를 검사하는 간단한 예시입니다.

regexCopy code

\+?\d{1,3}?[-.\s]?\(?\d{1,3}\)?[-.\s]?\d{1,4}[-.\s]?\d{1,4}

이 정규식은 국제 코드(선택적), 지역 코드(괄호 내에 있을 수 있음), 그리고 번호를 포함하여 다양한 형태의 전화번호와 일치합니다.

4. 비밀번호 복잡성 검사

보안 강화를 위해 특정 조건을 만족하는 비밀번호를 검사하는 정규식입니다.

regexCopy code

^(?=.*[a-z])(?=.*[A-Z])(?=.*\d)(?=.*[@$!%*?&])[A-Za-z\d@$!%*?&]{8,}$

이 정규식은 적어도 하나의 소문자, 대문자, 숫자, 특수 문자를 포함하고 총 8자 이상인 비밀번호와 일치합니다.

5. 코드에서 주석 제거

프로그래밍 코드에서 C 스타일의 주석을 제거할 때 사용할 수 있는 정규식입니다.

regexCopy code

/\*[^*]*\*+(?:[^/*][^*]*\*+)*/

이 정규식은 /*로 시작하고 */로 끝나는 멀티라인 주석을 찾아냅니다.

6. HTML 태그 제거

웹 페이지나 다른 HTML 소스에서 모든 태그를 제거하고 텍스트만 추출하려면 다음과 같은 정규식을 사용할 수 있습니다.

regexCopy code

<[^>]+>

이 정규식은 <로 시작하고 >로 끝나는 모든 문자열과 일치하여, HTML 태그를 찾아내고 제거합니다.

정규식은 이러한 예시 외에도 로그 분석, 데이터 추출, 입력 검증 등 다양한 분야에서 매우 유용하게 활용됩니다. 각 경우에 맞게 적절한 패턴을 설계하여 활용할 수 있습니다.

주의사항

정규식은 매우 강력하지만, 오용하면 의도치 않은 결과를 초래할 수 있습니다. 복잡하고 긴 정규식은 가독성을 저하시키고, 유지보수가 어려울 수 있습니다. 따라서 간결하고 명확한 패턴 설계가 중요합니다.

정규식은 다양한 프로그래밍 언어 및 도구에서 필수적인 요소로 자리 잡고 있습니다. 그 효용성 덕분에 데이터 검증, 처리, 분석 작업에서 빈번히 사용됩니다.

일단 정규식이라 함은 다들 아시겠지만 문자열이 특정한 패턴에 해당하는지 검사하거나 특정 패턴을 가진 부분을

추출하기 위해서 사용합니다.

문자열을 파싱해서 할 수도있지만 비용이 많이 드는 반면에 정규식을 사용하면 정확하고 빠르게 수행을 할 수 있고,

다른 많은 언어에서도 지원을 하니 뭐 많이들 사용하시는 자바스크립트 등에서 효과적으로 사용할 수 있는 장점이 있을 것 같고요...

정규식 문법을 알아야 한다는 단점이 있을 거 같습니다.

일단 정규식은 공식적으로 jdk 1.4 버전 이상에서 사용할 수 있습니다.

그래서... 가장 큰 장점은 자바 api에서 공식 지원하므로 까다로운 메서드나 클래스를 만들지않고 바로 사용할 수 있다는 점을 꼽고 싶습니다.

정규식은 자바 예약어와 같은 역할을 하는 특수문자들이 있습니다.

정규식을 보면 첨에 보면 좀 당황하게 되는 부분이 괄호였습니다. 괄호의 쓰임새를 보겠습니다.

괄호는 (), {}, [] 일케 3 종류를 씁니다.

()는 괄호 안에 있는 문자나 문자열을 하나의 문자처럼 취급을 합니다.

예를 들어 (aa) 일케 하면 꼭 aa 라는 것이죠~~

{}는 괄호 앞에 있는 문자의 반복횟수를 나타냅니다.

{2}는 문자가 두번 반복된다. {2,}는 문자가 두번 이상 반복된다. {2, 5}는 문자가 2번 이상 5번 이하로 반복된다.

(aa)하고 a{2} 하고는 같은 패턴인 것을 알 수 있습니다.

[]는 하나의 문자를 나타냅니다. char 라고 보셔도 무관할 거 같습니다.

근데 []는 범위를 줄 수도 있습니다. 범위를 주는 방법은 두가지가 있습니다.

첫번째는 [aeho] 이런 방식입니다. 이것은 어떤 한 문자가 'a' or 'e' or 'h' or 'o' 라는 것을 나타냅니다.

두번째는 -를 사용하는 방법입니다. [a-d] 일케하면 'a' or 'b' or 'c' or 'd' 라는 것을 나타냅니다.

이 두가지 방식을 함께 사용할 수도 있는데...[a-zA-Z] 일케하면 다들 아시겠지만...

영문자를 나타냅니다.

그렇다면 괄호를 함께 사용해서 (kor[1-3]{2,}ea){2} 이런 정규식은 kor22eakor312ea 와 같은 문자열을 나타낼 수 있겟죠...

[]괄호의 안에있는 범위중 특정한 것들을 골라서 미리 정해놓은 것이 있습니다. 이것이 '정규식 클래스'입니다.

[a-zA-Z] == \p{Alpha}, [0-9] == \p{Digit}, [ \t\n\x0B\f\r] == \p{Space} 등등... api에 자세히 나와있습니다.

다음으로 기호를 보겠습니다.

일단 .(쩜) 입니다.

.(쩜)은 하나의 문자를 나타냅니다. a.b 라는 패턴은 a랑 b사이에 하나의 문자가 꼭 있어야 한다는 패턴입니다.

a..b는 a랑 b사이에 꼭 두개의 문자가 있어야 한다는 패턴이 됩니다.

근데 우낀건 이 .(쩜) 자체를 나타낼려면 특수문자 이므로 \를 붙여줘야 하는데

이 .(쩜)이 [] 안에 쓰이면 즉 [.] == \. 이 되어버립니다. 즉 . != \. == [.] == [\.] 이라는 얘기지요

이유는 모르겠지만... [] 자체가 하나의 케릭터를 나타내기 때문에 [.]도 .(쩜) 문자로 취급을 하는 거 같습니다.

아까 위에서 a[.]b하면 a랑 b사이에 꼭 .(쩜) 문자가 있어야 한다는 패턴이라는 얘기지요. 즉 a/.b == a[.] 가 됩니다.

^ 문자는 문자열의 맨앞을 나타냅니다. ^Aeho 하면 문자열이 Aeho로 시작한다는 패턴이 됩니다.

이 ^가 []안에 쓰이면 not(!)의 의미를 같습니다. [^a-zA-Z] 는 영문자가 아니다 라는 패턴이 됩니다.

$ 문자는 문자열의 끝을 나타냅니다. Aeho$ 하면 문자열이 Aeho로 끝난다는 패턴이 됩니다.

| 문자는 or를 나타냅니다. |문자 자체를 나타낼려면 \|를 해야 합니다.

흔희 String 클래스의 split() 메서드가 제대로 안짤릴 때가 있다는 사람들이 있습니다.

그래서 StringTokenizer객체를 사용하고는 하던데요... 잘못된 정규식 사용 때문이라고 생각합니다.

split()은 인자로 정규식 패턴을 받고 StringTokenizer 는 실제 문자열을 구분자의 인자로 받습니다. 실재로 이들은 기능이 좀 다릅니다. 각각의 사용 용법이 다르다고 생각합니다. String.split()이 제대로 동작하지 않는다면 api 그것도 java.lang.String클래스에 멤서드로 등록이 되있을 수가 없을 것입니다...ㅋㅋ

"ab|cd|ef" 라는 문자열을 split("|") 하게되면 배열이 a,b,c,d,e,f 로 짤릴 것입니다. split("\\|") 하게되면 ab, cd, ef 로 짤릴 것입니다. 이유는 다들 잘 아실겁니다.

스플릿이 잘 짤릴 때도 있고 안될 때도 있다고 하시는 사람들은 대부분 그 구분자를 정규식에서 사용하는 특수

문자(대표적으로 |)를 사용할려고 하기때문에 또 그 때 \를 잘 사용을 하지 않아서 그런 경우라고 생각합니다.

String 클래스에 있는 trim() 메서드를 정규식으로 구현한다면...

public String trim() {
return this.str.replaceAll("^\\p{Space}|\\p{Space}$", "");
} 정도가 되지 않을까 싶습니다. 아님 말고요...ㅋㅋ

다음은... 반복 횟수를 나타내는 기호들입니다.
* 기호는 앞에있는 패턴이 0번 이상 출현함을 나타냅니다. ".*" 은 모든 문자열을 나타냅니다.
+ 기호는 앞에있는 패턴이 1번 이상 출현함을 나타냅니다. {1,} 이 녀석이랑 같은 의미가 될 거 같습니다.
? 기호는 앞에있는 패턴이 0 or 1 번 출현함을 나타냅니다. {0, 1} 이 녀것이 되겠네요.

이 정도만 알면 정규식을 읽고 쓸 수 있었습니다....ㅋㅋ, 더이상 알고 싶지않습니다.

필요하다면 api에 자세히 나와있죠... 역시 공식지원이라 좋군요...ㅎㅎ

이 번에는 정규식 그룹을 보겠습니다. 그룹은 api 보면 설명이 나왔습니다만...
()의 중복된 순서를 나타냅니다. 예를 들어 (A)(B(C)) 이와같은 패턴이 있다면...괄호가 열려진 순서대로 그룹의 번호가 정해집니다. group(0) 번은 항상 패턴 전체를 나타냅니다. group(1)은 (A) 패턴입니다. group(2)은 (B(C)) 가 되고, group(3) 은 (C) 이 됩니다.

이 그룹은 java.util.regex.Matcher 클래스를 이용하여 사용할 수 있는데요...
예를 들어 어떤 문자열이 있는데... 그 전체 문자열 중에서 url 정보를 가져오고 나서 실제로 그 url의 프로토콜을 알아보고자 한다면 프로토콜 부분의 패턴을 ()로 묶어주면 group(1) 을 이용하여 가져올 수 있게 됩니다.

다른 쓸 말이 많지만... 일단 이 정도만 정리해 보겠습니다.
힘드네요... 헉헉...

[이 게시물은 하나를하더라도최선을님에 의해 2024-04-17 15:18:37 자유게시판에서 이동 됨]

[VB.NET] 파일 저장 시 유효하지 않은 파일명에 대한 특수 문자 처리 및 복구 방법

하나를하더라도최선을 — 2024-04-17T15:16:23+09:00

    Public Function StringToFileName(fName As String) As String
        Dim V() As String = {"%", "\", "/", ":", "*", "?", """", "<", ">", "|"} '// 변환시
        Dim str As String = fName
        For Each T As String In V
            Dim s As String = CStr(Asc(T))
            If s.Length < 3 Then
                s = "0" & s
                s = String.Format("%{0}", Microsoft.VisualBasic.Right(s, 2))
            Else
                s = "0" & s
                s = Microsoft.VisualBasic.Right(s, 4)
                s = String.Format("%{0}%{1}", s.Substring(0, 2), s.Substring(2, 2))
            End If
            str = Replace$(str, T, s)
        Next
        Return str
    End Function
    Public Function FileNameToString(fName As String) As String
        Dim V() As String = {"\", "/", ":", "*", "?", """", "<", ">", "|", "%"} '// 복구시
        Dim str As String = fName
        For Each T As String In V
            Dim s As String = CStr(Asc(T))
            If s.Length < 3 Then
                s = "0" & s
                s = String.Format("%{0}", Microsoft.VisualBasic.Right(s, 2))
            Else
                s = "0" & s
                s = Microsoft.VisualBasic.Right(s, 4)
                s = String.Format("%{0}%{1}", s.Substring(0, 2), s.Substring(2, 2))
            End If
            str = Replace$(str, s, T)
        Next
        Return str
    End Function
​
파일명을 안전하게 저장하고, 추후에 원본 파일명을 정확하게 복구할 수 있는 VB.NET 함수를 작성해 보겠습니다. 이를 위해 금지된 문자를 유니코드 값으로 변환하고, 특정 접두사를 사용하여 이러한 치환을 식별할 수 있게 합니다. 이 방식은 복구가 가능하며, 충돌을 방지합니다.
파일명 치환 함수vbCopy code
Public Function ReplaceInvalidFileNameChars(fileName As String) As String

    Dim invalidChars As Char() = System.IO.Path.GetInvalidFileNameChars()

    Dim safeFileName As New System.Text.StringBuilder(fileName)



    For Each c As Char In invalidChars

        safeFileName.Replace(c, "_U" + AscW(c).ToString("X4"))

    Next



    Return safeFileName.ToString()

End Function
파일명 복구 함수vbCopy code
Public Function RecoverFileName(safeFileName As String) As String

    Dim recoveredFileName As New System.Text.StringBuilder(safeFileName)



    ' 순차적으로 Unicode 포인트에 해당하는 문자를 복구합니다.

    Dim regex As New System.Text.RegularExpressions.Regex("_U([0-9A-F]{4})")

    Dim m As System.Text.RegularExpressions.Match = regex.Match(safeFileName)



    While m.Success

        Dim unicodeChar As Char = ChrW(Convert.ToInt32(m.Groups(1).Value, 16))

        recoveredFileName.Replace(m.Value, unicodeChar)

        m = m.NextMatch()

    End While



    Return recoveredFileName.ToString()

End Function
사용법 및 설명치환 함수 (ReplaceInvalidFileNameChars): 파일 이름에 포함된 모든 유효하지 않은 문자를 해당 유니코드 값으로 치환합니다. 예를 들어, \는 _U005C로 변환됩니다.
복구 함수 (RecoverFileName): 치환된 문자열을 검사하여 _UXXXX 형식을 갖는 모든 문자를 원래의 문자로 복구합니다. 여기서 XXXX는 문자의 유니코드 포인트입니다.
이 방식을 사용하면, 파일 이름에 원래 _UXXXX 형식의 문자열이 포함되어 있더라도 이를 올바르게 처리할 수 있습니다. 단, 파일 이름에 _U와 네 자리 숫자가 자연스럽게 포함되는 경우에도 이를 원래 문자로 잘못 복구할 수 있는 위험이 있으므로, 이 점을 유의하여 사용해야 합니다. 가능하다면, 사용 환경에서 _UXXXX 패턴이 자연스럽게 발생할 가능성이 낮은지 확인해야 합니다.

[이 게시물은 하나를하더라도최선을님에 의해 2024-04-17 15:18:17 자유게시판에서 이동 됨]

Chrome webdriver Headless모드

하나를하더라도최선을 — 2024-01-09T13:13:51+09:00

크롬 버전이 60버전 이상인 크롬에서는 ‘Headless’모드를 사용할 수 있습니다.

Dim chromeOptions As New ChromeOptions()

chromeOptions.AddArgument("--headless") '// Headless모드

chromeOptions.AddArgument("--window-size=1920x1080")

chromeOptions.AddArgument("--disable-gpu") '// gpu(그래픽카드 가속)를 사용하지 않음

chromeOptions.AddArgument("--user-agent=" & USER_AGENT)

iWD = New ChromeDriver(service, chromeOptions, TimeSpan.FromSeconds(30))

Headless 브라우저임을 숨기기
Headless 모드는 CLI 기반의 서버 OS에서도 Selenium을 통한 크롤링/테스트를 가능하게 만드는 멋진 모드지만, 어떤 서버들에서는 이런 Headless 모드를 감지하는 여러 가지 방법을 쓸 수 있습니다. 

[vb.net] 'Microsoft.Jet.OLEDB.12.0' 공급자는 로컬 컴퓨터에 등록할 수 없습니다.

하나를하더라도최선을 — 2023-11-24T15:49:53+09:00

몇 년 전, Microsoft Office 2010 이전에는 개발자의 삶이 좀 더 편했습니다. Office는 32비트였습니다.

아시다시피 Microsoft Office 2010 이후로 우리 시대는 좀 더 복잡해졌습니다. 사용자는 64비트 기본 버전의 Office도 설치할 수 있습니다.

이는 개발자에게 OLEDB 공급자를 사용하여 Excel 또는 Access 파일에 연결하는 32비트 응용 프로그램이 64비트 Office 2010 설치에 32비트 공급자가 없을 수 있으므로 더 이상 작동하지 않을 수 있음을 의미합니다.

이러한 경우 사용자가 자신의 컴퓨터에 유효한 Microsoft Office 2010을 설치했더라도 응용 프로그램에서 다음과 같은 오류가 발생할 수 있습니다.

'Microsoft.Jet.OLEDB.4.0' 공급자는 로컬 컴퓨터에 등록할 수 없습니다.
'Microsoft.Jet.OLEDB.12.0' 공급자는 로컬 컴퓨터에 등록할 수 없습니다.

이러한 문제를 해결하기 위해 Microsoft는 "Microsoft Access Database Engine 2010 재배포 가능 패키지" 라는 새로운 재배포 가능 패키지를 출시했습니다 . 이 재배포 가능 패키지는 Microsoft ACE OLEDB Provider의 32비트 또는 64비트 버전을 제공하며 여기에서 다운로드할 수 있습니다.

http://www.microsoft.com/downloads/en/details.aspx?familyid=C06B8369-60DD-4B64-A44B-84B371EDE16D&displaylang=en

따라서 개발자로서 Office 2010이 64비트 설치되어 있는 컴퓨터(예: CodeFluent Entities Access Importer )에서 이 OLEDB 공급자를 사용하는 32비트 응용 프로그램이 있는 경우 32비트 버전의 Office 2010을 설치해야 합니다. 공급자.

2007 'Office System Driver: 데이터 연결 구성 요소'를 다운받으라고 하는데..

해당 다운로드 페이지는 404 오류가 뜬다!

(https://www.microsoft.com/en-us/download/details.aspx?id=23734)

각각의 파일을 실행해보면 64비트는 설치가 되지만 32비트 AccessDatabaseEngine.exe 설치 시 "Microsoft Office SharePoint Designer 2010, Microsoft Office Professional Plus 2010, Microsoft Office Visio 2010" 제품을 삭제하라며 오류가 발생.

이럴 때는 cmd 명령창을 통해 AccessDatabaseEngine.exe를 실행한다.

설치 팁

현재 Office가 설치된 컴퓨터(예: 64의 32)가 아닌 컴퓨터에서 Microsoft ACE OLEDB 공급자 설치를 시작하면 설치가 실패합니다. 제대로 실행하려면 " /passive " 인수가 지정된 명령줄에서 실행해야 합니다.

Office 2010 64비트를 실행하는 컴퓨터에 Microsoft ACE OLEDB Provider 32비트를 설치하려면:

$> AccessDatabaseEngine.exe /passive

Office 2010 32비트를 실행하는 컴퓨터에 Microsoft ACE OLEDB Provider 64비트를 설치하려면:

$> AccessDatabaseEngine_X64.exe /passive

" cd downloads " 입력 후 엔터 > " AccessDatabaseEngine.exe /passive "를 입력 후 enter를 치면 설치가 진행된다.

설치가 완료된 후 엑셀 기능을 실행하면 오류가 발생하지 않는다.

도움이 되었기를 바랍니다

[vb.net] Ctrl + C, Ctrl + V 사용하기

하나를하더라도최선을 — 2023-11-22T10:57:35+09:00

PreviewKeyDown 이벤트를 활용해서 아주 간단하게 텍스트 박스에서 Ctrl + c, Ctrl + v, Ctrl + a, Ctrl + z ... 등 단축키가 가능하게 설정할 수 있습니다.

    Private Sub TextBox1_PreviewKeyDown(sender As Object, e As PreviewKeyDownEventArgs) Handles TextBox1.PreviewKeyDown

        If e.Control Then e.IsInputKey = True

    End Sub

내 프로젝트에서 모든 텍스트 박스에 적용하고자 한다면 사용자 정의 컨트롤을 만들어 사용하면 됩니다.

Public Class TextBox

    Inherits Windows.Forms.TextBox

    Private Overloads Sub OnPreviewKeyDown(e As PreviewKeyDownEventArgs)

        MyBase.OnPreviewKeyDown(e)

        If e.Control Then e.IsInputKey = True

    End Sub

End Class

파일같이 첨부합니다.

또한 스튜디오 버전에 따라 다를 수 있으므로 상황에 따라 아래와 같이 이벤트를 활용해야 할 수도 있습니다.

Private Sub textBox1_KeyDown(ByVal sender As Object, ByVal e As KeyEventArgs)

    Me.OnKeyDown(e)

    If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.C Then

        textBox1.Copy()

    End If

    If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.V Then

        Me.textBox1.Paste()

    End If

    If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.X Then

        Me.textBox1.Cut()

    End If

    If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.A Then

        Me.textBox1.SelectAll()

    End If

    If e.Modifiers = Keys.Control AndAlso e.KeyCode = Keys.Z Then

        Me.textBox1.Undo()

    End If

End Sub